Da sie to jakos ustawic?

[v3ko]

Siema ! Mam pytanie
Mam na serwerze wgrany Advanced Bans ,ale gdy banuje nie pisze np. Admin v3ko zbanowal tylko pisze Admin 4fun+bf2 zbanowal Da sie to jakos ustawic na Admin ****** zbanowal?
SS : http://img96.imageshack.us/img96/9225/awpcity0002s.png

[powerman3]

wgraj sobie minibans

[v3ko]

Ale minibans ,zle banuje ;< Tzn daje bana kolesiowi ,a ten sobie wbija po 1 sek.

[powerman3]

najwyrazniej miales zlego, sciagnij sobie napisanego przez sebe

[v3ko]

No mam 0.6 ,a to chyba tego seba napisal ;/ bany sie wyswietlaja ,ale po daniu bana nawet kolesiowi ze steamem i wraca mi odrazu :/.

[naven]

O minibans szkoda gadać.
Daj kod.

[v3ko]

Jaki kod?? ^^ ten ktory znajduje sie w .sma? tylko ze minibans nie posiada pliku .sma ;/ A najlepiej mi powiedz gdzie go znajde Ps. jestem ciemny w tych sprawach ;//.
to jest w pliku .amx

[naven]

Advanced bans, nie minibans

[v3ko]

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN_NAME    "Advanced Bans"
#define PLUGIN_VERSION    "0.1"
#define PLUGIN_AUTHOR    "Exolent"

#pragma semicolon 1


#define BANLIST_INTERVAL    10
#define UNBAN_INTERVAL        5.0

new Array:g_names;
new Array:g_steamids;
new Array:g_banlengths;
new Array:g_unbantimes;
new Array:g_reasons;
new Array:g_admin_names;
new Array:g_admin_steamids;

new g_total_bans;

new g_ban_file[64];

new ab_website;
new ab_immunity;

new g_unban_ent;

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
    register_cvar("advanced_bans", PLUGIN_VERSION, FCVAR_SPONLY);
    
    register_dictionary("advanced_bans.txt");
    
    register_concmd("amx_ban", "CmdBan", ADMIN_BAN, "<nick, #userid, authid> <time in minutes> <reason>");
    register_concmd("amx_banip", "CmdBanIp", ADMIN_BAN, "<nick, #userid, authid> <time in minutes> <reason>");
    register_concmd("amx_addban", "CmdAddBan", ADMIN_BAN, "<name> <authid or ip> <time in minutes> <reason>");
    register_concmd("amx_unban", "CmdUnban", ADMIN_BAN, "<authid or ip>");
    register_concmd("amx_banlist", "CmdBanList", ADMIN_BAN, "[start] -- shows everyone who is banned");
    
    ab_website = register_cvar("ab_website", "");
    ab_immunity = register_cvar("ab_immunity", "1");
    
    get_datadir(g_ban_file, sizeof(g_ban_file) - 1);
    add(g_ban_file, sizeof(g_ban_file) - 1, "/advanced_bans.txt");
    
    g_names = ArrayCreate(64);
    g_steamids = ArrayCreate(64);
    g_banlengths = ArrayCreate(1);
    g_unbantimes = ArrayCreate(32);
    g_reasons = ArrayCreate(128);
    g_admin_names = ArrayCreate(64);
    g_admin_steamids = ArrayCreate(35);
    
    LoadBans();
    
    new info_target = engfunc(EngFunc_AllocString, "info_target");
    do
    {
        g_unban_ent = engfunc(EngFunc_CreateNamedEntity, info_target);
    }
    while( !pev_valid(g_unban_ent) );
    
    register_forward(FM_Think, "FwdThink");
    
    set_pev(g_unban_ent, pev_nextthink, get_gametime() + UNBAN_INTERVAL);
}

public client_authorized(client)
{
    new authid[35];
    get_user_authid(client, authid, sizeof(authid) - 1);
    
    new ip[64];
    get_user_ip(client, ip, sizeof(ip) - 1, 1);
    
    new banned_authid[64], bool:is_ip;
    for( new i = 0; i < g_total_bans; i++ )
    {
        ArrayGetString(g_steamids, i, banned_authid, sizeof(banned_authid) - 1);
        
        is_ip = bool:(containi(banned_authid, ".") != -1);
        
        if( is_ip && equal(ip, banned_authid) || !is_ip && equal(authid, banned_authid) )
        {
            new website[64];
            get_pcvar_string(ab_website, website, sizeof(website) - 1);
            
            new name[32], reason[128], unbantime[32], admin_name[32], admin_steamid[64];
            ArrayGetString(g_names, i, name, sizeof(name) - 1);
            ArrayGetString(g_reasons, i, reason, sizeof(reason) - 1);
            new banlength = ArrayGetCell(g_banlengths, i);
            ArrayGetString(g_unbantimes, i, unbantime, sizeof(unbantime) - 1);
            ArrayGetString(g_admin_names, i, admin_name, sizeof(admin_name) - 1);
            ArrayGetString(g_admin_steamids, i, admin_steamid, sizeof(admin_steamid) - 1);
            
            console_print(client, "************************************************");
            console_print(client, "%L:", client, "AB_BAN_INFORMATION");
            console_print(client, "%L: %s", client, "AB_NAME", name);
            console_print(client, "%L: %s", client, is_ip ? "AB_IP" : "AB_STEAMID", banned_authid);
            console_print(client, "%L: %s", client, "AB_REASON", reason);
            if( banlength > 0 )
            {
                new length[64];
                GetBanTime(banlength, length, sizeof(length) - 1);
                
                console_print(client, "%L: %s", client, "AB_BAN_LENGTH", length);
            }
            console_print(client, "%L: %s", client, "AB_UNBAN_TIME", unbantime);
            console_print(client, "%L: %s", client, "AB_ADMIN_NAME", admin_name);
            console_print(client, "%L: %s", client, "AB_ADMIN_STEAMID", admin_steamid);
            if( website[0] )
            {
                console_print(client, "");
                console_print(client, "%L", client, "AB_WEBSITE");
                console_print(client, "%s", website);
            }
            console_print(client, "************************************************");
            
            set_task(1.0, "TaskDisconnectPlayer", client);
            break;
        }
    }
}

public CmdBan(client, level, cid)
{
    if( !cmd_access(client, level, cid, 4) ) return PLUGIN_HANDLED;
    
    new arg[128];
    read_argv(1, arg, sizeof(arg) - 1);
    
    new target = cmd_target(client, arg, GetTargetFlags(client));
    if( !target ) return PLUGIN_HANDLED;
    
    new target_authid[35];
    get_user_authid(target, target_authid, sizeof(target_authid) - 1);
    
    if( !IsValidAuthid(target_authid) )
    {
        console_print(client, "[AdvancedBans] %L", client, "AB_NOT_AUTHORIZED");
        return PLUGIN_HANDLED;
    }
    
    new banned_authid[64];
    for( new i = 0; i < g_total_bans; i++ )
    {
        ArrayGetString(g_steamids, i, banned_authid, sizeof(banned_authid) - 1);
        
        if( equal(target_authid, banned_authid) )
        {
            console_print(client, "[AdvancedBans] %L", client, "AB_ALREADY_BANNED_STEAMID");
            return PLUGIN_HANDLED;
        }
    }
    
    read_argv(2, arg, sizeof(arg) - 1);
    
    new length = str_to_num(arg);
    new unban_time[64];
    
    if( length == 0 )
    {
        formatex(unban_time, sizeof(unban_time) - 1, "%L", client, "AB_PERMANENT_BAN");
    }
    else
    {
        GenerateUnbanTime(length, unban_time, sizeof(unban_time) - 1);
    }
    
    read_argv(3, arg, sizeof(arg) - 1);
    
    new admin_name[64], target_name[64];
    get_user_name(client, admin_name, sizeof(admin_name) - 1);
    get_user_name(target, target_name, sizeof(target_name) - 1);
    
    new admin_authid[35];
    get_user_authid(client, admin_authid, sizeof(admin_authid) - 1);
    
    AddBan(target_name, target_authid, arg, length, unban_time, admin_name, admin_authid);
    
    new website[64];
    get_pcvar_string(ab_website, website, sizeof(website) - 1);
    
    new banlength[64];
    if( length > 0 )
    {
        GetBanTime(length, banlength, sizeof(banlength) - 1);
    }
    
    console_print(target, "************************************************");
    console_print(target, "%L:", target, "AB_BAN_INFORMATION");
    console_print(target, "%L: %s", target, "AB_NAME", target_name);
    console_print(target, "%L: %s", target, "AB_STEAMID", target_authid);
    console_print(target, "%L: %s", target, "AB_REASON", arg);
    if( length > 0 )
    {
        console_print(target, "%L: %s", target, "AB_BAN_LENGTH", banlength);
    }
    console_print(target, "%L: %s", target, "AB_UNBAN_TIME", unban_time);
    console_print(target, "%L: %s", target, "AB_ADMIN_NAME", admin_name);
    console_print(target, "%L: %s", target, "AB_ADMIN_STEAMID", admin_authid);
    if( website[0] )
    {
        console_print(target, "");
        console_print(target, "%L", target, "AB_WEBSITE");
        console_print(target, "%s", website);
    }
    console_print(target, "************************************************");
    
    set_task(1.0, "TaskDisconnectPlayer", target);
    
    console_print(client, "************************************************");
    console_print(client, "%L:", client, "AB_BAN_INFORMATION");
    console_print(client, "%L: %s", client, "AB_NAME", target_name);
    console_print(client, "%L: %s", client, "AB_STEAMID", target_authid);
    console_print(client, "%L: %s", client, "AB_REASON", arg);
    if( length > 0 )
    {
        console_print(client, "%L: %s", client, "AB_BAN_LENGTH", banlength);
    }
    console_print(client, "%L: %s", client, "AB_UNBAN_TIME", unban_time);
    console_print(client, "************************************************");
    
    Print("^x04[AdvancedBans] %s^x01 :^x03  banned %s. Reason: %s. UnBan Time: %s", admin_name, target_name, arg, unban_time);
    
    log_amx("%s <%s> banned %s <%s> || Reason: ^"%s^" || UnBan Time: %s", admin_name, admin_authid, target_name, target_authid, arg, unban_time);
    
    return PLUGIN_HANDLED;
}

public CmdBanIp(client, level, cid)
{
    if( !cmd_access(client, level, cid, 4) ) return PLUGIN_HANDLED;
    
    new arg[128];
    read_argv(1, arg, sizeof(arg) - 1);
    
    new target = cmd_target(client, arg, GetTargetFlags(client));
    if( !target ) return PLUGIN_HANDLED;
    
    new target_ip[35];
    get_user_ip(target, target_ip, sizeof(target_ip) - 1, 1);
    
    new banned_authid[64];
    for( new i = 0; i < g_total_bans; i++ )
    {
        ArrayGetString(g_steamids, i, banned_authid, sizeof(banned_authid) - 1);
        
        if( containi(banned_authid, ".") != -1 && equal(target_ip, banned_authid) )
        {
            console_print(client, "[AdvancedBans] %L", client, "AB_ALREADY_BANNED_IP");
            return PLUGIN_HANDLED;
        }
    }
    
    read_argv(2, arg, sizeof(arg) - 1);
    
    new length = str_to_num(arg);
    new unban_time[64];
    
    if( length == 0 )
    {
        formatex(unban_time, sizeof(unban_time) - 1, "%L", client, "AB_PERMANENT_BAN");
    }
    else
    {
        GenerateUnbanTime(length, unban_time, sizeof(unban_time) - 1);
    }
    
    read_argv(3, arg, sizeof(arg) - 1);
    
    new admin_name[64], target_name[64];
    get_user_name(client, admin_name, sizeof(admin_name) - 1);
    get_user_name(target, target_name, sizeof(target_name) - 1);
    
    new admin_authid[35];
    get_user_authid(client, admin_authid, sizeof(admin_authid) - 1);
    
    AddBan(target_name, target_ip, arg, length, unban_time, admin_name, admin_authid);
    
    new website[64];
    get_pcvar_string(ab_website, website, sizeof(website) - 1);
    
    new banlength[64];
    if( length > 0 )
    {
        GetBanTime(length, banlength, sizeof(banlength) - 1);
    }
    
    console_print(target, "************************************************");
    console_print(target, "%L:", target, "AB_BAN_INFORMATION");
    console_print(target, "%L: %s", target, "AB_NAME", target_name);
    console_print(target, "%L: %s", target, "AB_IP", target_ip);
    console_print(target, "%L: %s", target, "AB_REASON", arg);
    if( length > 0 )
    {
        console_print(target, "%L: %s", target, "AB_BAN_LENGTH", banlength);
    }
    console_print(target, "%L: %s", target, "AB_UNBAN_TIME", unban_time);
    console_print(target, "%L: %s", target, "AB_ADMIN_NAME", admin_name);
    console_print(target, "%L: %s", target, "AB_ADMIN_STEAMID", admin_authid);
    if( website[0] )
    {
        console_print(target, "");
        console_print(target, "%L", target, "AB_WEBSITE");
        console_print(target, "%s", website);
    }
    console_print(target, "************************************************");
    
    set_task(1.0, "TaskDisconnectPlayer", target);
    
    console_print(client, "************************************************");
    console_print(client, "%L:", client, "AB_BAN_INFORMATION");
    console_print(client, "%L: %s", client, "AB_NAME", target_name);
    console_print(client, "%L: %s", client, "AB_IP", target_ip);
    console_print(client, "%L: %s", client, "AB_REASON", arg);
    if( length > 0 )
    {
        console_print(client, "%L: %s", client, "AB_BAN_LENGTH", banlength);
    }
    console_print(client, "%L: %s", client, "AB_UNBAN_TIME", unban_time);
    console_print(client, "************************************************");
    
    Print("^x04[AdvancedBans] %s^x01 :^x03  banned %s. Reason: %s. UnBan Time: %s", admin_name, target_name, arg, unban_time);
    
    log_amx("%s <%s> banned %s <%s> || Reason: ^"%s^" || UnBan Time: %s", admin_name, admin_authid, target_name, target_ip, arg, unban_time);
    
    return PLUGIN_HANDLED;
}

public CmdAddBan(client, level, cid)
{
    if( !cmd_access(client, level, cid, 5) ) return PLUGIN_HANDLED;
    
    new target_name[64], target_authid[35], bantime[10], reason[128];
    read_argv(1, target_name, sizeof(target_name) - 1);
    read_argv(2, target_authid, sizeof(target_authid) - 1);
    read_argv(3, bantime, sizeof(bantime) - 1);
    read_argv(4, reason, sizeof(reason) - 1);
    
    new bool:is_ip = bool:(containi(target_authid, ".") != -1);
    
    if( !is_ip && !IsValidAuthid(target_authid) )
    {
        console_print(client, "[AdvancedBans] %L", client, "AB_INVALID_STEAMID");
        console_print(client, "[AdvancedBans] %L", client, "AB_VALID_STEAMID_FORMAT");
        
        return PLUGIN_HANDLED;
    }
    
    new length = str_to_num(bantime);
    
    new target = cmd_target(client, target_authid, 0);
    if( !target ) target = find_player(is_ip ? "d" : "c", target_authid);
    if( is_user_connected(target) )
    {
        client_cmd(client, "amx_ban ^"%s^" %i ^"%s^"", target_authid, length, reason);
        return PLUGIN_HANDLED;
    }
    
    new unban_time[64];
    if( length == 0 )
    {
        formatex(unban_time, sizeof(unban_time) - 1, "%L", client, "AB_PERMANENT_BAN");
    }
    else
    {
        GenerateUnbanTime(length, unban_time, sizeof(unban_time) - 1);
    }
    
    new admin_name[64], admin_authid[35];
    get_user_name(client, admin_name, sizeof(admin_name) - 1);
    get_user_name(client, admin_authid, sizeof(admin_authid) - 1);
    
    AddBan(target_name, target_authid, reason, length, unban_time, admin_name, admin_authid);
    
    console_print(client, "************************************************");
    console_print(client, "%L:", client, "AB_BAN_INFORMATION");
    console_print(client, "%L: %s", client, "AB_NAME", target_name);
    console_print(client, "%L: %s", client, is_ip ? "AB_IP" : "AB_STEAMID", target_authid);
    console_print(client, "%L: %s", client, "AB_REASON", reason);
    if( length > 0 )
    {
        new banlength[64];
        GetBanTime(length, banlength, sizeof(banlength) - 1);
        
        console_print(client, "%L: %s", client, "AB_BAN_LENGTH", banlength);
    }
    console_print(client, "%L: %s", client, "AB_UNBAN_TIME", unban_time);
    console_print(client, "************************************************");
    
    Print("^x04[AdvancedBans] %s^x01 :^x03  banned %s %s. Reason: %s. UnBan Time: %s", admin_name, is_ip ? "IP" : "SteamID", target_authid, reason, unban_time);
    
    log_amx("%s <%s> banned %s <%s> || Reason: ^"%s^" || UnBan Time: %s", admin_name, admin_authid, target_name, target_authid, reason, unban_time);
    
    return PLUGIN_HANDLED;
}

public CmdUnban(client, level, cid)
{
    if( !cmd_access(client, level, cid, 2) ) return PLUGIN_HANDLED;
    
    new arg[35];
    read_argv(1, arg, sizeof(arg) - 1);
    
    new banned_authid[64];
    for( new i = 0; i < g_total_bans; i++ )
    {
        ArrayGetString(g_steamids, i, banned_authid, sizeof(banned_authid) - 1);
        
        if( equal(arg, banned_authid) )
        {
            new admin_name[64];
            get_user_name(client, admin_name, sizeof(admin_name) - 1);
            
            new name[32], reason[128];
            ArrayGetString(g_names, i, name, sizeof(name) - 1);
            ArrayGetString(g_reasons, i, reason, sizeof(reason) - 1);
            
            Print("^x04[AdvancedBans] %s^x01 :^x03  unbanned %s^x01 [%s] [Ban Reason: %s]", admin_name, name, arg, reason);
            
            new authid[35];
            get_user_authid(client, authid, sizeof(authid) - 1);
            
            log_amx("%s <%s> unbanned %s <%s> || Ban Reason: ^"%s^"", admin_name, authid, name, arg, reason);
            
            RemoveBan(i);
            
            return PLUGIN_HANDLED;
        }
    }
    
    console_print(client, "[AdvancedBans] %L", client, "AB_NOT_IN_BAN_LIST", arg);
    
    return PLUGIN_HANDLED;
}

public CmdBanList(client, level, cid)
{
    if( !cmd_access(client, level, cid, 1) ) return PLUGIN_HANDLED;
    
    if( !g_total_bans )
    {
        console_print(client, "[AdvancedBans] %L", client, "AB_NO_BANS");
        return PLUGIN_HANDLED;
    }
    
    new start;
    
    if( read_argc() > 1 )
    {
        new arg[5];
        read_argv(1, arg, sizeof(arg) - 1);
        
        start = str_to_num(arg) - 1;
        
        if( start >= g_total_bans )
        {
            start = g_total_bans - 1;
        }
    }
    else
    {
        start = 0;
    }
    
    new last = min(start + BANLIST_INTERVAL, g_total_bans);
    
    console_print(client, "%L", client, "AB_BAN_LIST_NUM", start + 1, last);
    
    new lname[64], lsteamid[64], lip[64], lreason[64], lbanlength[64], lunbantime[64], ladminname[64], ladminsteamid[64];
    formatex(lname, sizeof(lname) - 1, "%L", client, "AB_NAME");
    formatex(lsteamid, sizeof(lsteamid) - 1, "%L", client, "AB_STEAMID");
    formatex(lip, sizeof(lip) - 1, "%L", client, "AB_IP");
    formatex(lreason, sizeof(lreason) - 1, "%L", client, "AB_REASON");
    formatex(lbanlength, sizeof(lbanlength) - 1, "%L", client, "AB_BAN_LENGTH");
    formatex(lunbantime, sizeof(lunbantime) - 1, "%L", client, "AB_UNBAN_TIME");
    formatex(ladminname, sizeof(ladminname) - 1, "%L", client, "AB_ADMIN_NAME");
    formatex(ladminsteamid, sizeof(ladminsteamid) - 1, "%L", client, "AB_ADMIN_STEAMID");
    
    new name[32], steamid[64], reason[128], banlength, length[64], unbantime[32], admin_name[32], admin_steamid[35];
    for( new i = start; i < last; i++ )
    {
        ArrayGetString(g_names, i, name, sizeof(name) - 1);
        ArrayGetString(g_steamids, i, steamid, sizeof(steamid) - 1);
        ArrayGetString(g_reasons, i, reason, sizeof(reason) - 1);
        banlength = ArrayGetCell(g_banlengths, i);
        ArrayGetString(g_unbantimes, i, unbantime, sizeof(unbantime) - 1);
        ArrayGetString(g_admin_names, i, admin_name, sizeof(admin_name) - 1);
        ArrayGetString(g_admin_steamids, i, admin_steamid, sizeof(admin_steamid) - 1);
        
        console_print(client, "************************************************");
        console_print(client, "%s: %s", lname, name);
        console_print(client, "%s: %s", containi(steamid, ".") != -1 ? lip : lsteamid, steamid);
        console_print(client, "%s: %s", lreason, reason);
        if( banlength > 0 )
        {
            GetBanTime(banlength, length, sizeof(length) - 1);
            console_print(client, "%s: %s", lbanlength, length);
        }
        console_print(client, "%s: %s", lunbantime, unbantime);
        console_print(client, "%s: %s", ladminname, admin_name);
        console_print(client, "%s: %s", ladminsteamid, admin_steamid);
    }
    
    console_print(client, "************************************************");
    
    if( ++last < g_total_bans )
    {
        console_print(client, "%L", client, "AB_BAN_LIST_NEXT", last);
    }
    
    return PLUGIN_HANDLED;
}

public FwdThink(ent)
{
    if( ent != g_unban_ent
    || !g_total_bans )
    {
        return;
    }
    
    new _hours[5], _minutes[5], _seconds[5], _month[5], _day[5], _year[7];
    format_time(_hours, sizeof(_hours) - 1, "%H");
    format_time(_minutes, sizeof(_minutes) - 1, "%M");
    format_time(_seconds, sizeof(_seconds) - 1, "%S");
    format_time(_month, sizeof(_month) - 1, "%m");
    format_time(_day, sizeof(_day) - 1, "%d");
    format_time(_year, sizeof(_year) - 1, "%Y");
    
    // c = current
    // u = unban
    
    new c_hours = str_to_num(_hours);
    new c_minutes = str_to_num(_minutes);
    new c_seconds = str_to_num(_seconds);
    new c_month = str_to_num(_month);
    new c_day = str_to_num(_day);
    new c_year = str_to_num(_year);
    
    new unban_time[64];
    new u_hours, u_minutes, u_seconds, u_month, u_day, u_year;
    
    new name[32], steamid[64], reason[128];
    for( new i = 0; i < g_total_bans; i++ )
    {
        if( ArrayGetCell(g_banlengths, i) == 0 ) continue;
        
        ArrayGetString(g_unbantimes, i, unban_time, sizeof(unban_time) - 1);
        replace_all(unban_time, sizeof(unban_time) - 1, ":", " ");
        replace_all(unban_time, sizeof(unban_time) - 1, "/", " ");
        
        parse(unban_time,
            _hours, sizeof(_hours) - 1,
            _minutes, sizeof(_minutes) - 1,
            _seconds, sizeof(_seconds) - 1,
            _month, sizeof(_month) - 1,
            _day, sizeof(_day) - 1,
            _year, sizeof(_year) - 1
            );
        
        u_hours = str_to_num(_hours);
        u_minutes = str_to_num(_minutes);
        u_seconds = str_to_num(_seconds);
        u_month = str_to_num(_month);
        u_day = str_to_num(_day);
        u_year = str_to_num(_year);
        
        if( u_year < c_year
        || u_year == c_year && u_month < c_month
        || u_year == c_year && u_month == c_month && u_day < c_day
        || u_year == c_year && u_month == c_month && u_day == c_day && u_hours < c_hours
        || u_year == c_year && u_month == c_month && u_day == c_day && u_hours == c_hours && u_minutes < c_minutes
        || u_year == c_year && u_month == c_month && u_day == c_day && u_hours == c_hours && u_minutes == c_minutes && u_seconds <= c_seconds )
        {
            ArrayGetString(g_names, i, name, sizeof(name) - 1);
            ArrayGetString(g_steamids, i, steamid, sizeof(steamid) - 1);
            ArrayGetString(g_reasons, i, reason, sizeof(reason) - 1);
            
            log_amx("Ban time is up for: %s [%s]", name, steamid);
            
            Print("^x04[AdvancedBans]^x03 %s^x01[^x04%s^x01]^x03 ban time is up!^x01 [Ban Reason: %s]", name, steamid, reason);
            
            RemoveBan(i);
            
            i--; // current pos was replaced with another ban, so we need to check it again.
        }
    }
    
    if( g_total_bans )
    {
        set_pev(g_unban_ent, pev_nextthink, get_gametime() + UNBAN_INTERVAL);
    }
}

public TaskDisconnectPlayer(client)
{
    server_cmd("kick #%i ^"You are banned from this server. Check your console^"", get_user_userid(client));
}

AddBan(const target_name[], const target_steamid[], const reason[], const length, const unban_time[], const admin_name[], const admin_steamid[])
{
    new f = fopen(g_ban_file, "a+");
    
    fprintf(f, "^"%s^" ^"%s^" %i ^"%s^" ^"%s^" ^"%s^" ^"%s^"^n",
        target_steamid,
        target_name,
        length,
        unban_time,
        reason,
        admin_name,
        admin_steamid
        );
    
    fclose(f);
    
    ArrayPushString(g_names, target_name);
    ArrayPushString(g_steamids, target_steamid);
    ArrayPushCell(g_banlengths, length);
    ArrayPushString(g_unbantimes, unban_time);
    ArrayPushString(g_reasons, reason);
    ArrayPushString(g_admin_names, admin_name);
    ArrayPushString(g_admin_steamids, admin_steamid);
    
    g_total_bans++;
}

RemoveBan(remove)
{
    ArrayDeleteItem(g_names, remove);
    ArrayDeleteItem(g_steamids, remove);
    ArrayDeleteItem(g_banlengths, remove);
    ArrayDeleteItem(g_unbantimes, remove);
    ArrayDeleteItem(g_reasons, remove);
    ArrayDeleteItem(g_admin_names, remove);
    ArrayDeleteItem(g_admin_steamids, remove);
    
    g_total_bans--;
    
    // file will be deleted upon fopen with flags "wt"
    //delete_file(g_ban_file);
    
    new f = fopen(g_ban_file, "wt");
    
    new name[32], steamid[64], banlength, unbantime[32], reason[128], admin_name[32], admin_steamid[35];
    for( new i = 0; i < g_total_bans; i++ )
    {
        ArrayGetString(g_names, i, name, sizeof(name) - 1);
        ArrayGetString(g_steamids, i, steamid, sizeof(steamid) - 1);
        banlength = ArrayGetCell(g_banlengths, i);
        ArrayGetString(g_unbantimes, i, unbantime, sizeof(unbantime) - 1);
        ArrayGetString(g_reasons, i, reason, sizeof(reason) - 1);
        ArrayGetString(g_admin_names, i, admin_name, sizeof(admin_name) - 1);
        ArrayGetString(g_admin_steamids, i, admin_steamid, sizeof(admin_steamid) - 1);
        
        fprintf(f, "^"%s^" ^"%s^" %i ^"%s^" ^"%s^" ^"%s^" ^"%s^"^n",
            steamid,
            name,
            banlength,
            unbantime,
            reason,
            admin_name,
            admin_steamid
            );
    }
    
    fclose(f);
}

LoadOldBans(filename[])
{
    if( file_exists(filename) )
    {
        new f = fopen(filename, "rt");
        
        new data[96];
        new command[10], minutes[10], steamid[35], length, unban_time[32];
        
        while( !feof(f) )
        {
            fgets(f, data, sizeof(data) - 1);
            if( !data[0] ) continue;
            
            parse(data, command, sizeof(command) - 1, minutes, sizeof(minutes) - 1, steamid, sizeof(steamid) - 1);
            if( filename[0] == 'b' && !equali(command, "banid") || filename[0] == 'l' && !equali(command, "addip") ) continue;
            
            length = str_to_num(minutes);
            GenerateUnbanTime(length, unban_time, sizeof(unban_time) - 1);
            
            AddBan("", steamid, "", length, unban_time, "", "");
        }
        
        fclose(f);
        
        new filename2[32];
        
        // copy current
        copy(filename2, sizeof(filename2) - 1, filename);
        
        // cut off at the .
        // banned.cfg = banned
        // listip.cfg = listip
        filename2[containi(filename2, ".")] = 0;
        
        // add 2.cfg
        // banned = banned2.cfg
        // listip = listip2.cfg
        add(filename2, sizeof(filename2) - 1, "2.cfg");
        
        // rename file so that it isnt loaded again
        while( !rename_file(filename, filename2, 1) ) { }
    }
}

LoadBans()
{
    if( file_exists(g_ban_file) )
    {
        new f = fopen(g_ban_file, "rt");
        
        new data[512], name[32], steamid[64], length[10], unbantime[32], reason[128], admin_name[32], admin_steamid[35];
        
        while( !feof(f) )
        {
            fgets(f, data, sizeof(data) - 1);
            
            if( !data[0] ) continue;
            
            parse(data,
                steamid, sizeof(steamid) - 1,
                name, sizeof(name) - 1,
                length, sizeof(length) - 1,
                unbantime, sizeof(unbantime) - 1,
                reason, sizeof(reason) - 1,
                admin_name, sizeof(admin_name) - 1,
                admin_steamid, sizeof(admin_steamid) - 1
                );
            
            ArrayPushString(g_names, name);
            ArrayPushString(g_steamids, steamid);
            ArrayPushCell(g_banlengths, str_to_num(length));
            ArrayPushString(g_unbantimes, unbantime);
            ArrayPushString(g_reasons, reason);
            ArrayPushString(g_admin_names, admin_name);
            ArrayPushString(g_admin_steamids, admin_steamid);
            
            g_total_bans++;
        }
        
        fclose(f);
    }
    else
    {
        fclose(fopen(g_ban_file, "wt"));
    }
    
    // load these after, so when they are added to the file with AddBan(), they aren't loaded again from above.
    
    LoadOldBans("banned.cfg");
    LoadOldBans("listip.cfg");
}

GetBanTime(const bantime, length[], len)
{
    new minutes = bantime;
    new hours = 0;
    new days = 0;
    
    while( minutes >= 60 )
    {
        minutes -= 60;
        hours++;
    }
    
    while( hours >= 24 )
    {
        hours -= 24;
        days++;
    }
    
    new bool:add_before;
    if( minutes )
    {
        formatex(length, len, "%i minute%s", minutes, minutes == 1 ? "" : "s");
        
        add_before = true;
    }
    if( hours )
    {
        if( add_before )
        {
            format(length, len, "%i hour%s, %s", hours, hours == 1 ? "" : "s", length);
        }
        else
        {
            formatex(length, len, "%i hour%s", hours, hours == 1 ? "" : "s");
            
            add_before = true;
        }
    }
    if( days )
    {
        if( add_before )
        {
            format(length, len, "%i day%s, %s", days, days == 1 ? "" : "s", length);
        }
        else
        {
            formatex(length, len, "%i day%s", days, days == 1 ? "" : "s");
            
            add_before = true;
        }
    }
    if( !add_before )
    {
        // minutes, hours, and days = 0
        // assume permanent ban
        copy(length, len, "Permanent Ban");
    }
}

GenerateUnbanTime(const bantime, unban_time[], len)
{
    new _hours[5], _minutes[5], _seconds[5], _month[5], _day[5], _year[7];
    format_time(_hours, sizeof(_hours) - 1, "%H");
    format_time(_minutes, sizeof(_minutes) - 1, "%M");
    format_time(_seconds, sizeof(_seconds) - 1, "%S");
    format_time(_month, sizeof(_month) - 1, "%m");
    format_time(_day, sizeof(_day) - 1, "%d");
    format_time(_year, sizeof(_year) - 1, "%Y");
    
    new hours = str_to_num(_hours);
    new minutes = str_to_num(_minutes);
    new seconds = str_to_num(_seconds);
    new month = str_to_num(_month);
    new day = str_to_num(_day);
    new year = str_to_num(_year);
    
    minutes += bantime;
    
    while( minutes >= 60 )
    {
        minutes -= 60;
        hours++;
    }
    
    while( hours >= 24 )
    {
        hours -= 24;
        day++;
    }
    
    new max_days = GetDaysInMonth(month, year);
    while( day > max_days )
    {
        day -= max_days;
        month++;
    }
    
    while( month > 12 )
    {
        month -= 12;
        year++;
    }
    
    formatex(unban_time, len, "%i:%02i:%02i %i/%i/%i", hours, minutes, seconds, month, day, year);
}

GetDaysInMonth(month, year=0)
{
    switch( month )
    {
        case 1:        return 31; // january
        case 2:        return ((year % 4) == 0) ? 29 : 28; // february
        case 3:        return 31; // march
        case 4:        return 30; // april
        case 5:        return 31; // may
        case 6:        return 30; // june
        case 7:        return 31; // july
        case 8:        return 31; // august
        case 9:        return 30; // september
        case 10:    return 31; // october
        case 11:    return 30; // november
        case 12:    return 31; // december
    }
    
    return 30;
}

GetTargetFlags(client)
{
    static const flags_no_immunity = (CMDTARGET_ALLOW_SELF|CMDTARGET_NO_BOTS);
    static const flags_immunity = (CMDTARGET_ALLOW_SELF|CMDTARGET_NO_BOTS|CMDTARGET_OBEY_IMMUNITY);
    
    switch( get_pcvar_num(ab_immunity) )
    {
        case 1: return flags_immunity;
        case 2: return access(client, ADMIN_IMMUNITY) ? flags_no_immunity : flags_immunity;
    }
    
    return flags_no_immunity;
}

bool:IsValidAuthid(const authid[])
{
    // invalid steamids:
    //     STEAM_ID_PENDING
    //     STEAM_ID_LAN
    //     VALVE_ID_LAN
    //    VALVE_ID_PENDING
    //    HLTV
    //    4294967295 -- taken from admincmd.sma
    
    return (authid[0] && equal(authid, "STEAM_0:", 8));
}

Print(const message_fmt[], any:...)
{
    if( !get_playersnum() ) return;
    
    static message[192];
    vformat(message, sizeof(message) - 1, message_fmt, 2);
    
    static msgid_SayText;
    if( !msgid_SayText )
    {
        msgid_SayText = get_user_msgid("SayText");
    }
    
    static max_clients;
    if( !max_clients )
    {
        max_clients = get_maxplayers();
    }
    
    for( new client = 1; client <= max_clients; client++ )
    {
        if( !is_user_connected(client) ) continue;
        
        message_begin(MSG_ONE_UNRELIABLE, msgid_SayText, _, client);
        write_byte(client);
        write_string(message);
        message_end();
    }
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/ 

To jest kod .sma pliku advanced bans.

[naven]

Używaj tagów [php] albo [code]!!!
Daj jeszcze plik językowy i powiedz, który tekst ma być zmieniony

[v3ko]

Zmień mi to Gracz Battlefield2 zbanowal itd. na Admin V3ko zbanował V3ko powód : .... tak jak w amxbans jest czy cos rozumiesz chyba no nie? A i jeszcze dalo by sie ustawic zeby wyswietalo mi wiadomosc w HUDzie?
plmenu:

/* AMX Mod X
*   Players Menu Plugin
*
* by the AMX Mod X Development Team
*  originally developed by OLO
*
* This file is part of AMX Mod X.
*
*
*  This program is free software; you can redistribute it and/or modify it
*  under the terms of the GNU General Public License as published by the
*  Free Software Foundation; either version 2 of the License, or (at
*  your option) any later version.
*
*  This program is distributed in the hope that it will be useful, but
*  WITHOUT ANY WARRANTY; without even the implied warranty of
*  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
*  General Public License for more details.
*
*  You should have received a copy of the GNU General Public License
*  along with this program; if not, write to the Free Software Foundation,
*  Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
*
*  In addition, as a special exception, the author gives permission to
*  link the code of this program with the Half-Life Game Engine ("HL
*  Engine") and Modified Game Libraries ("MODs") developed by Valve,
*  L.L.C ("Valve"). You must obey the GNU General Public License in all
*  respects for all of the code used other than the HL Engine and MODs
*  from Valve. If you modify this file, you may extend this exception
*  to your version of the file, but you are not obligated to do so. If
*  you do not wish to do so, delete this exception statement from your
*  version.
*/

#include <amxmodx>
#include <amxmisc>

/** skip autoloading since it's optional */
#define AMXMODX_NOAUTOLOAD
#include <cstrike>

new g_menuPosition[33]
new g_menuPlayers[33][32]
new g_menuPlayersNum[33]
new g_menuOption[33]
new g_menuSettings[33]

new g_menuSelect[33][64]
new g_menuSelectNum[33]

#define MAX_CLCMDS 24

new g_clcmdName[MAX_CLCMDS][32]
new g_clcmdCmd[MAX_CLCMDS][64]
new g_clcmdMisc[MAX_CLCMDS][2]
new g_clcmdNum

new g_coloredMenus
new g_cstrike = 0

new Array:g_bantimes;
new Array:g_slapsettings;

new g_CSTeamNames[3][] = {
    "TERRORIST",
    "CT",
    "SPECTATOR"
}
new g_CSTeamNumbers[3][] = {
    "1",
    "2",
    "6"
}
new g_CSTeamiNumbers[3] = {
    1,
    2,
    6
}

new g_ban_player[33];


public plugin_natives()
{
    set_module_filter("module_filter")
    set_native_filter("native_filter")
}

public plugin_init()
{
    register_plugin("Players Menu", AMXX_VERSION_STR, "AMXX Dev Team")
    register_dictionary("common.txt")
    register_dictionary("admincmd.txt")
    register_dictionary("plmenu.txt")

    register_clcmd("amx_kickmenu", "cmdKickMenu", ADMIN_KICK, "- displays kick menu")
    register_clcmd("amx_banmenu", "cmdBanMenu", ADMIN_BAN, "- displays ban menu")
    register_clcmd("amx_slapmenu", "cmdSlapMenu", ADMIN_SLAY, "- displays slap/slay menu")
    register_clcmd("amx_teammenu", "cmdTeamMenu", ADMIN_LEVEL_A, "- displays team menu")
    register_clcmd("amx_clcmdmenu", "cmdClcmdMenu", ADMIN_LEVEL_A, "- displays client cmds menu")
    register_clcmd("amx_banreason", "CmdBanReason", ADMIN_BAN, "<reason>");

    register_menucmd(register_menuid("Ban Menu"), 1023, "actionBanMenu")
    register_menucmd(register_menuid("Kick Menu"), 1023, "actionKickMenu")
    register_menucmd(register_menuid("Slap/Slay Menu"), 1023, "actionSlapMenu")
    register_menucmd(register_menuid("Team Menu"), 1023, "actionTeamMenu")
    register_menucmd(register_menuid("Client Cmds Menu"), 1023, "actionClcmdMenu")
    
    
    g_bantimes = ArrayCreate();
    // Load up the old default values
    ArrayPushCell(g_bantimes, 0);
    ArrayPushCell(g_bantimes, 5);
    ArrayPushCell(g_bantimes, 10);
    ArrayPushCell(g_bantimes, 15);
    ArrayPushCell(g_bantimes, 30);
    ArrayPushCell(g_bantimes, 45);
    ArrayPushCell(g_bantimes, 60);
    
    
    g_slapsettings = ArrayCreate();
    // Old default values
    ArrayPushCell(g_slapsettings, 0); // First option is ignored - it is slay
    ArrayPushCell(g_slapsettings, 0); // slap 0 damage
    ArrayPushCell(g_slapsettings, 1);
    ArrayPushCell(g_slapsettings, 5);
    
    
    register_srvcmd("amx_plmenu_bantimes", "plmenu_setbantimes");
    register_srvcmd("amx_plmenu_slapdmg", "plmenu_setslapdmg");

    g_coloredMenus = colored_menus()

    new clcmds_ini_file[64]
    get_configsdir(clcmds_ini_file, 63)
    format(clcmds_ini_file, 63, "%s/clcmds.ini", clcmds_ini_file)
    load_settings(clcmds_ini_file)

    if (module_exists("cstrike"))
        g_cstrike = 1
}
public plmenu_setbantimes()
{
    new buff[32];
    new args = read_argc();
    
    if (args <= 1)
    {
        server_print("usage: amx_plmenu_bantimes <time1> [time2] [time3] ...");
        server_print("   use time of 0 for permanent.");
        
        return;
    }
    
    ArrayClear(g_bantimes);
    
    for (new i = 1; i < args; i++)
    {
        read_argv(i, buff, charsmax(buff));
        
        ArrayPushCell(g_bantimes, str_to_num(buff));
        
    }
    
}
public plmenu_setslapdmg()
{
    new buff[32];
    new args = read_argc();
    
    if (args <= 1)
    {
        server_print("usage: amx_plmenu_slapdmg <dmg1> [dmg2] [dmg3] ...");
        server_print("   slay is automatically set for the first value.");
        
        return;
    }
    
    ArrayClear(g_slapsettings);
    
    ArrayPushCell(g_slapsettings, 0); // compensate for slay
    
    for (new i = 1; i < args; i++)
    {
        read_argv(i, buff, charsmax(buff));
        
        ArrayPushCell(g_slapsettings, str_to_num(buff));
        
    }
    
}
public module_filter(const module[])
{
    if (equali(module, "cstrike"))
        return PLUGIN_HANDLED
    
    return PLUGIN_CONTINUE
}

public native_filter(const name[], index, trap)
{
    if (!trap)
        return PLUGIN_HANDLED
        
    return PLUGIN_CONTINUE
}

/* Ban menu */

public client_disconnect(id)
{
    g_ban_player[id] = 0;
}

public CmdBanReason(id)
{
    new player = g_ban_player[id];
    
    if( !player ) return PLUGIN_HANDLED;
    
    new reason[128];
    read_args(reason, sizeof(reason) - 1);
    remove_quotes(reason);
    
    new name[32], name2[32], authid[32], authid2[32]

    get_user_name(player, name2, 31)
    get_user_authid(id, authid, 31)
    get_user_authid(player, authid2, 31)
    get_user_name(id, name, 31)
    
    new userid2 = get_user_userid(player)

    log_amx("Ban: ^"%s<%d><%s><>^" ban and kick ^"%s<%d><%s><>^" (minutes ^"%d^") (reason ^"%s^")", name, get_user_userid(id), authid, name2, userid2, authid2, g_menuSettings[id], reason)

    if ( !equal("STEAM_0:", authid2, 8))
    {
        server_cmd("amx_banip #%i %i ^"%s^"", userid2, g_menuSettings[id], reason);
    }
    else
    {
        server_cmd("amx_ban #%i %i ^"%s^"", userid2, g_menuSettings[id], reason);
    }

    server_exec()
    
    g_ban_player[id] = 0;

    displayBanMenu(id, g_menuPosition[id])
    
    return PLUGIN_HANDLED;
}

public actionBanMenu(id, key)
{
    switch (key)
    {
        case 7:
        {
            /* BEGIN OF CHANGES BY MISTAGEE ADDED A FEW MORE OPTIONS */
            
            ++g_menuOption[id]
            g_menuOption[id] %= ArraySize(g_bantimes);

            g_menuSettings[id] = ArrayGetCell(g_bantimes, g_menuOption[id]);

            displayBanMenu(id, g_menuPosition[id])
        }
        case 8: displayBanMenu(id, ++g_menuPosition[id])
        case 9: displayBanMenu(id, --g_menuPosition[id])
        default:
        {
            g_ban_player[id] = g_menuPlayers[id][g_menuPosition[id] * 7 + key]
            
            client_cmd(id, "messagemode amx_banreason");
            
            client_print(id, print_chat, "[AMXX] Type in the reason for banning this player.");
            
            
            /*new name[32], name2[32], authid[32], authid2[32]
        
            get_user_name(player, name2, 31)
            get_user_authid(id, authid, 31)
            get_user_authid(player, authid2, 31)
            get_user_name(id, name, 31)
            
            new userid2 = get_user_userid(player)

            log_amx("Ban: ^"%s<%d><%s><>^" ban and kick ^"%s<%d><%s><>^" (minutes ^"%d^")", name, get_user_userid(id), authid, name2, userid2, authid2, g_menuSettings[id])

            if (g_menuSettings[id]==0) // permanent
            {
                new maxpl = get_maxplayers();
                for (new i = 1; i <= maxpl; i++)
                {
                    show_activity_id(i, id, name, "%L %s %L", i, "BAN", name2, i, "PERM");
                }
            }
            else
            {
                new tempTime[32];
                formatex(tempTime,sizeof(tempTime)-1,"%d",g_menuSettings[id]);
                new maxpl = get_maxplayers();
                for (new i = 1; i <= maxpl; i++)
                {
                    show_activity_id(i, id, name, "%L %s %L", i, "BAN", name2, i, "FOR_MIN", tempTime);
                }
            }
            // ---------- check for Steam ID added by MistaGee -------------------- 
            // IF AUTHID == 4294967295 OR VALVE_ID_LAN OR HLTV, BAN PER IP TO NOT BAN EVERYONE
            
            if (equal("4294967295", authid2)
                || equal("HLTV", authid2)
                || equal("STEAM_ID_LAN", authid2)
                || equali("VALVE_ID_LAN", authid2))
            {
                // END OF MODIFICATIONS BY MISTAGEE 
                server_cmd("amx_banip #%i %i ^"Banned From Menu^"", userid2, g_menuSettings[id]);
            }
            else
            {
                server_cmd("amx_ban #%i %i ^"Banned From Menu^"", userid2, g_menuSettings[id]);
            }

            server_exec()

            displayBanMenu(id, g_menuPosition[id])*/
        }
    }
    
    return PLUGIN_HANDLED
}

displayBanMenu(id, pos)
{
    if (pos < 0)
        return

    get_players(g_menuPlayers[id], g_menuPlayersNum[id])

    new menuBody[512]
    new b = 0
    new i
    new name[32]
    new start = pos * 7

    if (start >= g_menuPlayersNum[id])
        start = pos = g_menuPosition[id] = 0

    new len = format(menuBody, 511, g_coloredMenus ? "\y%L\R%d/%d^n\w^n" : "%L %d/%d^n^n", id, "BAN_MENU", pos + 1, (g_menuPlayersNum[id] / 7 + ((g_menuPlayersNum[id] % 7) ? 1 : 0)))
    new end = start + 7
    new keys = MENU_KEY_0|MENU_KEY_8

    if (end > g_menuPlayersNum[id])
        end = g_menuPlayersNum[id]

    for (new a = start; a < end; ++a)
    {
        i = g_menuPlayers[id][a]
        get_user_name(i, name, 31)

        if (is_user_bot(i) || (access(i, ADMIN_IMMUNITY) && i != id))
        {
            ++b
            
            if (g_coloredMenus)
                len += format(menuBody[len], 511-len, "\d%d. %s^n\w", b, name)
            else
                len += format(menuBody[len], 511-len, "#. %s^n", name)
        } else {
            keys |= (1<<b)
                
            if (is_user_admin(i))
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s \r*^n\w" : "%d. %s *^n", ++b, name)
            else
                len += format(menuBody[len], 511-len, "%d. %s^n", ++b, name)
        }
    }

    if (g_menuSettings[id])
        len += format(menuBody[len], 511-len, "^n8. %L^n", id, "BAN_FOR_MIN", g_menuSettings[id])
    else
        len += format(menuBody[len], 511-len, "^n8. %L^n", id, "BAN_PERM")

    if (end != g_menuPlayersNum[id])
    {
        format(menuBody[len], 511-len, "^n9. %L...^n0. %L", id, "MORE", id, pos ? "BACK" : "EXIT")
        keys |= MENU_KEY_9
    }
    else
        format(menuBody[len], 511-len, "^n0. %L", id, pos ? "BACK" : "EXIT")

    show_menu(id, keys, menuBody, -1, "Ban Menu")
}

public cmdBanMenu(id, level, cid)
{
    if (!cmd_access(id, level, cid, 1))
        return PLUGIN_HANDLED

    g_menuOption[id] = 0
    
    if (ArraySize(g_bantimes) > 0)
    {
        g_menuSettings[id] = ArrayGetCell(g_bantimes, g_menuOption[id]);
    }
    else
    {
        // should never happen, but failsafe
        g_menuSettings[id] = 0
    }
    displayBanMenu(id, g_menuPosition[id] = 0)

    return PLUGIN_HANDLED
}

/* Slap/Slay */

public actionSlapMenu(id, key)
{
    switch (key)
    {
        case 7:
        {
            ++g_menuOption[id]
            
            g_menuOption[id] %= ArraySize(g_slapsettings);
            
            g_menuSettings[id] = ArrayGetCell(g_slapsettings, g_menuOption[id]);
            
            displaySlapMenu(id, g_menuPosition[id]);
        }
        case 8: displaySlapMenu(id, ++g_menuPosition[id])
        case 9: displaySlapMenu(id, --g_menuPosition[id])
        default:
        {
            new player = g_menuPlayers[id][g_menuPosition[id] * 7 + key]
            new name2[32]
            
            get_user_name(player, name2, 31)

            if (!is_user_alive(player))
            {
                client_print(id, print_chat, "%L", id, "CANT_PERF_DEAD", name2)
                displaySlapMenu(id, g_menuPosition[id])
                return PLUGIN_HANDLED
            }

            new authid[32], authid2[32], name[32]

            get_user_authid(id, authid, 31)
            get_user_authid(player, authid2, 31)
            get_user_name(id, name, 31)

            if (g_menuOption[id])
            {
                log_amx("Cmd: ^"%s<%d><%s><>^" slap with %d damage ^"%s<%d><%s><>^"", name, get_user_userid(id), authid, g_menuSettings[id], name2, get_user_userid(player), authid2)

                show_activity_key("ADMIN_SLAP_1", "ADMIN_SLAP_2", name, name2, g_menuSettings[id]);
            } else {
                log_amx("Cmd: ^"%s<%d><%s><>^" slay ^"%s<%d><%s><>^"", name, get_user_userid(id), authid, name2, get_user_userid(player), authid2)
                
                show_activity_key("ADMIN_SLAY_1", "ADMIN_SLAY_2", name, name2);
            }

            if (g_menuOption[id])
                user_slap(player, (get_user_health(player) > g_menuSettings[id]) ? g_menuSettings[id] : 0)
            else
                user_kill(player)

            displaySlapMenu(id, g_menuPosition[id])
        }
    }
    
    return PLUGIN_HANDLED
}

displaySlapMenu(id, pos)
{
    if (pos < 0)
        return

    get_players(g_menuPlayers[id], g_menuPlayersNum[id])

    new menuBody[512]
    new b = 0
    new i
    new name[32], team[4]
    new start = pos * 7

    if (start >= g_menuPlayersNum[id])
        start = pos = g_menuPosition[id] = 0

    new len = format(menuBody, 511, g_coloredMenus ? "\y%L\R%d/%d^n\w^n" : "%L %d/%d^n^n", id, "SLAP_SLAY_MENU", pos + 1, (g_menuPlayersNum[id] / 7 + ((g_menuPlayersNum[id] % 7) ? 1 : 0)))
    new end = start + 7
    new keys = MENU_KEY_0|MENU_KEY_8

    if (end > g_menuPlayersNum[id])
        end = g_menuPlayersNum[id]

    for (new a = start; a < end; ++a)
    {
        i = g_menuPlayers[id][a]
        get_user_name(i, name, 31)
        
        if (g_cstrike)
        {
            if (cs_get_user_team(i) == CS_TEAM_T)
            {
                copy(team, 3, "TE")
            }
            else if (cs_get_user_team(i) == CS_TEAM_CT)
            {
                copy(team, 3, "CT")
            } else {
                get_user_team(i, team, 3)
            }
        } else {
            get_user_team(i, team, 3)
        }

        if (!is_user_alive(i) || (access(i, ADMIN_IMMUNITY) && i != id))
        {
            ++b
        
            if (g_coloredMenus)
                len += format(menuBody[len], 511-len, "\d%d. %s\R%s^n\w", b, name, team)
            else
                len += format(menuBody[len], 511-len, "#. %s   %s^n", name, team)        
        } else {
            keys |= (1<<b)
                
            if (is_user_admin(i))
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s \r*\y\R%s^n\w" : "%d. %s *   %s^n", ++b, name, team)
            else
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s\y\R%s^n\w" : "%d. %s   %s^n", ++b, name, team)
        }
    }

    if (g_menuOption[id])
        len += format(menuBody[len], 511-len, "^n8. %L^n", id, "SLAP_WITH_DMG", g_menuSettings[id])
    else
        len += format(menuBody[len], 511-len, "^n8. %L^n", id, "SLAY")

    if (end != g_menuPlayersNum[id])
    {
        format(menuBody[len], 511-len, "^n9. %L...^n0. %L", id, "MORE", id, pos ? "BACK" : "EXIT")
        keys |= MENU_KEY_9
    }
    else
        format(menuBody[len], 511-len, "^n0. %L", id, pos ? "BACK" : "EXIT")

    show_menu(id, keys, menuBody, -1, "Slap/Slay Menu")
}

public cmdSlapMenu(id, level, cid)
{
    if (!cmd_access(id, level, cid, 1))
        return PLUGIN_HANDLED

    g_menuOption[id] = 0
    if (ArraySize(g_slapsettings) > 0)
    {
        g_menuSettings[id] = ArrayGetCell(g_slapsettings, g_menuOption[id]);
    }
    else
    {
        // should never happen, but failsafe
        g_menuSettings[id] = 0
    }

    displaySlapMenu(id, g_menuPosition[id] = 0)

    return PLUGIN_HANDLED
}

/* Kick */

public actionKickMenu(id, key)
{
    switch (key)
    {
        case 8: displayKickMenu(id, ++g_menuPosition[id])
        case 9: displayKickMenu(id, --g_menuPosition[id])
        default:
        {
            new player = g_menuPlayers[id][g_menuPosition[id] * 8 + key]
            new authid[32], authid2[32], name[32], name2[32]
            
            get_user_authid(id, authid, 31)
            get_user_authid(player, authid2, 31)
            get_user_name(id, name, 31)
            get_user_name(player, name2, 31)
            
            new userid2 = get_user_userid(player)

            log_amx("Kick: ^"%s<%d><%s><>^" kick ^"%s<%d><%s><>^"", name, get_user_userid(id), authid, name2, userid2, authid2)

            show_activity_key("ADMIN_KICK_1", "ADMIN_KICK_2", name, name2);

            
            server_cmd("kick #%d", userid2)
            server_exec()

            displayKickMenu(id, g_menuPosition[id])
        }
    }

    return PLUGIN_HANDLED
}

displayKickMenu(id, pos)
{
    if (pos < 0)
        return

    get_players(g_menuPlayers[id], g_menuPlayersNum[id])

    new menuBody[512]
    new b = 0
    new i
    new name[32]
    new start = pos * 8

    if (start >= g_menuPlayersNum[id])
        start = pos = g_menuPosition[id] = 0

    new len = format(menuBody, 511, g_coloredMenus ? "\y%L\R%d/%d^n\w^n" : "%L %d/%d^n^n", id, "KICK_MENU", pos + 1, (g_menuPlayersNum[id] / 8 + ((g_menuPlayersNum[id] % 8) ? 1 : 0)))
    new end = start + 8
    new keys = MENU_KEY_0

    if (end > g_menuPlayersNum[id])
        end = g_menuPlayersNum[id]

    for (new a = start; a < end; ++a)
    {
        i = g_menuPlayers[id][a]
        get_user_name(i, name, 31)

        if (access(i, ADMIN_IMMUNITY) && i != id)
        {
            ++b
        
            if (g_coloredMenus)
                len += format(menuBody[len], 511-len, "\d%d. %s^n\w", b, name)
            else
                len += format(menuBody[len], 511-len, "#. %s^n", name)
        } else {
            keys |= (1<<b)
                
            if (is_user_admin(i))
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s \r*^n\w" : "%d. %s *^n", ++b, name)
            else
                len += format(menuBody[len], 511-len, "%d. %s^n", ++b, name)
        }
    }

    if (end != g_menuPlayersNum[id])
    {
        format(menuBody[len], 511-len, "^n9. %L...^n0. %L", id, "MORE", id, pos ? "BACK" : "EXIT")
        keys |= MENU_KEY_9
    }
    else
        format(menuBody[len], 511-len, "^n0. %L", id, pos ? "BACK" : "EXIT")

    show_menu(id, keys, menuBody, -1, "Kick Menu")
}

public cmdKickMenu(id, level, cid)
{
    if (cmd_access(id, level, cid, 1))
        displayKickMenu(id, g_menuPosition[id] = 0)

    return PLUGIN_HANDLED
}

/* Team menu */

public actionTeamMenu(id, key)
{
    switch (key)
    {
        case 7:
        {
            g_menuOption[id] = (g_menuOption[id] + 1) % (g_cstrike ? 3 : 2);
            displayTeamMenu(id, g_menuPosition[id])
        }
        case 8: displayTeamMenu(id, ++g_menuPosition[id])
        case 9: displayTeamMenu(id, --g_menuPosition[id])
        default:
        {
            new player = g_menuPlayers[id][g_menuPosition[id] * 7 + key]
            new authid[32], authid2[32], name[32], name2[32]

            get_user_name(player, name2, 31)
            get_user_authid(id, authid, 31)
            get_user_authid(player, authid2, 31)
            get_user_name(id, name, 31)
                
            log_amx("Cmd: ^"%s<%d><%s><>^" transfer ^"%s<%d><%s><>^" (team ^"%s^")", name, get_user_userid(id), authid, name2, get_user_userid(player), authid2, g_menuOption[id] ? "TERRORIST" : "CT")

            show_activity_key("ADMIN_TRANSF_1", "ADMIN_TRANSF_2", name, name2, g_CSTeamNames[g_menuOption[id] % 3]);

            if (g_cstrike)
            {
                if (is_user_alive(player))
                {
                    new deaths = cs_get_user_deaths(player)
                    user_kill(player, 1)
                    cs_set_user_deaths(player, deaths)
                }
                // This modulo math just aligns the option to the CsTeams-corresponding number
                cs_set_user_team(player, (g_menuOption[id] % 3) + 1)
                cs_reset_user_model(player)
            } else {
                new limit_setting = get_cvar_num("mp_limitteams")
                
                set_cvar_num("mp_limitteams", 0)
                engclient_cmd(player, "jointeam", g_CSTeamNumbers[g_menuOption[id] % 2])
                engclient_cmd(player, "joinclass", "1")
                set_cvar_num("mp_limitteams", limit_setting)
            }

            displayTeamMenu(id, g_menuPosition[id])
        }
    }
    
    return PLUGIN_HANDLED
}

displayTeamMenu(id, pos)
{
    if (pos < 0)
        return

    get_players(g_menuPlayers[id], g_menuPlayersNum[id])

    new menuBody[512]
    new b = 0
    new i, iteam
    new name[32], team[4]
    new start = pos * 7

    if (start >= g_menuPlayersNum[id])
        start = pos = g_menuPosition[id] = 0

    new len = format(menuBody, 511, g_coloredMenus ? "\y%L\R%d/%d^n\w^n" : "%L %d/%d^n^n", id, "TEAM_MENU", pos + 1, (g_menuPlayersNum[id] / 7 + ((g_menuPlayersNum[id] % 7) ? 1 : 0)))
    new end = start + 7
    new keys = MENU_KEY_0|MENU_KEY_8

    if (end > g_menuPlayersNum[id])
        end = g_menuPlayersNum[id]

    for (new a = start; a < end; ++a)
    {
        i = g_menuPlayers[id][a]
        get_user_name(i, name, 31)
        
        if (g_cstrike)
        {
            iteam = _:cs_get_user_team(i)
            
            if (iteam == 1)
            {
                copy(team, 3, "TE")
            }
            else if (iteam == 2)
            {
                copy(team, 3, "CT")
            }
            else if (iteam == 3)
            {
                copy(team, 3, "SPE");
                iteam = 6;
            } else {
                iteam = get_user_team(i, team, 3)
            }
        } else {
            iteam = get_user_team(i, team, 3)
        }

        if ((iteam == g_CSTeamiNumbers[g_menuOption[id] % (g_cstrike ? 3 : 2)]) || (access(i, ADMIN_IMMUNITY) && i != id))
        {
            ++b
            
            if (g_coloredMenus)
                len += format(menuBody[len], 511-len, "\d%d. %s\R%s^n\w", b, name, team)
            else
                len += format(menuBody[len], 511-len, "#. %s   %s^n", name, team)        
        } else {
            keys |= (1<<b)
                
            if (is_user_admin(i))
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s \r*\y\R%s^n\w" : "%d. %s *   %s^n", ++b, name, team)
            else
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s\y\R%s^n\w" : "%d. %s   %s^n", ++b, name, team)
        }
    }

    len += format(menuBody[len], 511-len, "^n8. %L^n", id, "TRANSF_TO", g_CSTeamNames[g_menuOption[id] % (g_cstrike ? 3 : 2)])

    if (end != g_menuPlayersNum[id])
    {
        format(menuBody[len], 511-len, "^n9. %L...^n0. %L", id, "MORE", id, pos ? "BACK" : "EXIT")
        keys |= MENU_KEY_9
    }
    else
        format(menuBody[len], 511-len, "^n0. %L", id, pos ? "BACK" : "EXIT")

    show_menu(id, keys, menuBody, -1, "Team Menu")
}

public cmdTeamMenu(id, level, cid)
{
    if (!cmd_access(id, level, cid, 1))
        return PLUGIN_HANDLED

    g_menuOption[id] = 0

    displayTeamMenu(id, g_menuPosition[id] = 0)

    return PLUGIN_HANDLED
}

/* Client cmds menu */

public actionClcmdMenu(id, key)
{
    switch (key)
    {
        case 7:
        {
            ++g_menuOption[id]
            g_menuOption[id] %= g_menuSelectNum[id]
            displayClcmdMenu(id, g_menuPosition[id])
        }
        case 8: displayClcmdMenu(id, ++g_menuPosition[id])
        case 9: displayClcmdMenu(id, --g_menuPosition[id])
        default:
        {
            new player = g_menuPlayers[id][g_menuPosition[id] * 7 + key]
            new flags = g_clcmdMisc[g_menuSelect[id][g_menuOption[id]]][1]
            
            if (is_user_connected(player))
            {
                new command[512], authid[32], name[32], userid[32]
                
                copy(command, charsmax(command), g_clcmdCmd[g_menuSelect[id][g_menuOption[id]]])
                get_user_authid(player, authid, 31)
                get_user_name(player, name, 31)
                num_to_str(get_user_userid(player), userid, 31)
                
                replace(command, charsmax(command), "%userid%", userid)
                replace(command, charsmax(command), "%authid%", authid)
                replace(command, charsmax(command), "%name%", name)
                
                if (flags & 1)
                {
                    server_cmd("%s", command)
                    server_exec()
                } else if (flags & 2)
                    client_cmd(id, "%s", command)
                else if (flags & 4)
                    client_cmd(player, "%s", command)
            }
            
            if (flags & 8)
                displayClcmdMenu(id, g_menuPosition[id])
        }
    }
    
    return PLUGIN_HANDLED
}

displayClcmdMenu(id, pos)
{
    if (pos < 0)
        return

    get_players(g_menuPlayers[id], g_menuPlayersNum[id])

    new menuBody[512]
    new b = 0
    new i
    new name[32]
    new start = pos * 7

    if (start >= g_menuPlayersNum[id])
        start = pos = g_menuPosition[id] = 0

    new len = format(menuBody, 511, g_coloredMenus ? "\y%L\R%d/%d^n\w^n" : "%L %d/%d^n^n", id, "CL_CMD_MENU", pos + 1, (g_menuPlayersNum[id] / 7 + ((g_menuPlayersNum[id] % 7) ? 1 : 0)))
    new end = start + 7
    new keys = MENU_KEY_0|MENU_KEY_8

    if (end > g_menuPlayersNum[id])
        end = g_menuPlayersNum[id]

    for (new a = start; a < end; ++a)
    {
        i = g_menuPlayers[id][a]
        get_user_name(i, name, 31)

        if (!g_menuSelectNum[id] || (access(i, ADMIN_IMMUNITY) && i != id))
        {
            ++b
            
            if (g_coloredMenus)
                len += format(menuBody[len], 511-len, "\d%d. %s^n\w", b, name)
            else
                len += format(menuBody[len], 511-len, "#. %s^n", name)        
        } else {
            keys |= (1<<b)
                
            if (is_user_admin(i))
                len += format(menuBody[len], 511-len, g_coloredMenus ? "%d. %s \r*^n\w" : "%d. %s *^n", ++b, name)
            else
                len += format(menuBody[len], 511-len, "%d. %s^n", ++b, name)
        }
    }

    if (g_menuSelectNum[id])
        len += format(menuBody[len], 511-len, "^n8. %s^n", g_clcmdName[g_menuSelect[id][g_menuOption[id]]])
    else
        len += format(menuBody[len], 511-len, "^n8. %L^n", id, "NO_CMDS")

    if (end != g_menuPlayersNum[id])
    {
        format(menuBody[len], 511-len, "^n9. %L...^n0. %L", id, "MORE", id, pos ? "BACK" : "EXIT")
        keys |= MENU_KEY_9
    }
    else
        format(menuBody[len], 511-len, "^n0. %L", id, pos ? "BACK" : "EXIT")

    show_menu(id, keys, menuBody, -1, "Client Cmds Menu")
}

public cmdClcmdMenu(id, level, cid)
{
    if (!cmd_access(id, level, cid, 1))
        return PLUGIN_HANDLED

    g_menuSelectNum[id] = 0

    for (new a = 0; a < g_clcmdNum; ++a)
        if (access(id, g_clcmdMisc[a][0]))
            g_menuSelect[id][g_menuSelectNum[id]++] = a

    g_menuOption[id] = 0

    displayClcmdMenu(id, g_menuPosition[id] = 0)

    return PLUGIN_HANDLED
}

load_settings(szFilename[])
{
    if (!file_exists(szFilename))
        return 0

    new text[256], szFlags[32], szAccess[32]
    new a, pos = 0

    while (g_clcmdNum < MAX_CLCMDS && read_file(szFilename, pos++, text, 255, a))
    {
        if (text[0] == ';') continue

        if (parse(text, g_clcmdName[g_clcmdNum], 31, g_clcmdCmd[g_clcmdNum], 63, szFlags, 31, szAccess, 31) > 3)
        {
            while (replace(g_clcmdCmd[g_clcmdNum], 63, "\'", "^""))
            {
                // do nothing
            }

            g_clcmdMisc[g_clcmdNum][1] = read_flags(szFlags)
            g_clcmdMisc[g_clcmdNum][0] = read_flags(szAccess)
            g_clcmdNum++
        }
    }

    return 1
} 

[naven]

Po co mi plmenu? advanced_bans.txt

[v3ko]

[en]
AB_BAN_INFORMATION = Ban Information
AB_NAME = Name
AB_IP = IP
AB_STEAMID = SteamID
AB_REASON = Powod
AB_BAN_LENGTH = Dlugosc bana
AB_UNBAN_TIME = Czas pozostaly do unbana
AB_ADMIN_NAME = nick Admina
AB_ADMIN_STEAMID = Admin SteamID
AB_WEBSITE = Jesli twierdzisz ze zostales zbanowany niesprawiedliwie, poinformuj nas o tym na naszej stronie:
AB_NOT_AUTHORIZED = Target has not authorized with the server! Unable to ban!
AB_ALREADY_BANNED_STEAMID = SteamID tego gracza jest juz zbanowane!
AB_ALREADY_BANNED_IP = Te IP gracza jest juz zbanowane!
AB_PERMANENT_BAN = Permanent Ban
AB_INVALID_STEAMID = Invalid SteamID!
AB_VALID_STEAMID_FORMAT = Poprawny format: STEAM_0:X:XXXXXXX
AB_NOT_IN_BAN_LIST = Nie mozna znalezc %s na liscie banow!
AB_NO_BANS = There isnt anyone banned at this time.
AB_BAN_LIST_NUM = Listing banned players %i - %i.
AB_BAN_LIST_NEXT = Uzyj amx_banlist %i zeby zobaczyc liste zbanowanych osob.